テンプレートメソッド、ファクトリーパターン

テンプレートメソッドパターン

大本の汎用的なアルゴリズムを記述したテンプレートクラス



抽象インターフェース

package factory
{ 
 public interface IField
 {
  // 「フィールドを描く」というメソッドを定義
  function drawField():void;
 }
}

実装クラス

package factory
{
 public class FootballField implements IField
 {
  public function FootballField()
  {
  }
  
  public function drawField():void
  {
   trace('Drawing the Football Fieald!');
  }
 }
}

抽象テンプレートクラス

package factory
{
 /**
  *  テンプレートメソッド抽象クラス
  * 
  */ 
 public class BaseGame
 {
  public function BaseGame()
  {
  }
  
  public function initialize():void
  {
   // 無処理
  }
  
  public function createField():IField
  {
   throw new Error('createField:Abstract Methd!');
  }
 }
}

継承クラス

package factory
{
 /**
  *  テンプレートメソッドを継承するクラス
  * 
  */ 
 public class FootballGame extends BaseGame
 {
  public function FootballGame()
  {
   super();
  }
  
  override public function initialize():void
  {
   var field:IField = createField();
   field.drawField();
  }
  
  override public function createField():IField
  {
   return new FootballField();
  }
 }
}

コードだけでは理解するのが難しいので、クラス図を書いたほうがいい。

「テンプレートとなる抽象クラスで処理のアルゴリズムを書き、
抽象インターフェースで各処理の詳細を記述していく」

というイメージかな。

シングルトンパターン

デザインパターンの勉強を始めたので、その勉強録です。

まともに今までデザインパターンを勉強したことがなく、なんとなくソース読んで、似たような仕様で書くっていうのを今まで繰り返してました。
インターンの時にシングルトンを全く意味不明なまま使っていて、結局その時理解せずにインターンを終えてしまった苦い思い出が思い出されます。

今回はこの本に沿って、ActionScriptでデザインパターンを勉強していきたいと思います。(本当はC++とかでやりたい)
ActionScriptでデザインパターンを解説している唯一の本で、丁寧に解説してくれていて理解しやすいと思います。

---

シングルトンパターン

「クラスのインスタンスを一つしか作らない」ようにするパターンです。
静的なデータとかこういった形で持つ事が多いですかね。

SingletonEnforcerクラス
シングルトンのクラスのみが使用できるSingletonEnforcerクラスをコンストラクタの引数にして、強制的にコンストラクタを外部で呼び出せなくする手法。

package
{
 /**
  *  シングルトンパターンクラス
  * 
  */ 
 public class SingletonClass
 {
  // privateでstaticな変数
  private static var _instance:SingletonClass;
  
  /**
   * constructor 
   * 
   */  
  public function SingletonClass(enforcer:SingletonEnforcer)
  {
  }
  
  /**
   * インスタンス取得メソッド 
   * @return SingletonClass
   * 
   */  
  public static function getInstance():SingletonClass
  {
   if (SingletonClass._instance == null)
   {
    SingletonClass._instance = new SingletonClass(new SingletonEnforcer());
   }
   return SingletonClass._instance;
  }
  
  public function sayHello():void
  {
   trace('Hello World');
  }
 }
}
/**
 * コンストラクタを強制的に呼び出せなくするため
 * 外部からアクセス不可能な空クラスを定義
 * 
 */
class SingletonEnforcer {}